Hideous Bloat and Active Links.

By popular demand I've expanded my Emacs wiki from one function to an unwieldy two. The second function will scamper through a buffer and list all the active links found.

I use the same regexp that I did in the previous article so it links on CamelCase. To change the link style you just change the regexp. If you end up writing too many support functions then you may want to use that "variable" thing that all the cool kids are talking about.

The Code

(defun list-active-links (link-re &optional is-active-link-p)
  "Scan a buffer looking for links and list all the active links.

LINK-RE is a regular expression which matches the link text.
IS-ACTIVE-LINK-P is an optional function which takes the link text and
returns true if the link is active.  If not provided, `file-exists-p' is
used."
  (let ((buffer-name "*ActiveLinks*")
    (found-links ()))

    (if (not is-active-link-p)
    (setq is-active-link-p 'file-exists-p))

    ;; Gather up all the potential links and whether they're active.
    (save-excursion
      (goto-char (point-min))
      (while (re-search-forward link-re nil t)
    (let ((link-text (match-string-no-properties 0)))
      ;; If the link hasn't been checked, then save its value
      ;; and whether or not it has an existing destination.
      (if (not (assoc link-text found-links))
          (setq found-links
            (cons (cons link-text
                (funcall is-active-link-p link-text))
              found-links))))))

    ;; Now list out the active links.
    (if (get-buffer buffer-name)
    (kill-buffer buffer-name))
    (switch-to-buffer-other-window buffer-name)
    (let ((active-links
       ;; Remove any links that don't have an associated file.
       (delq nil (mapcar (lambda (x) (and (cdr x) (car x)))
                 found-links))))
      (insert "#\n# The following links have destinations.\n#\n")
      (save-excursion
    (insert (mapconcat 'identity (sort active-links 'string<) "\n")))
      (not-modified)
      (message "%d matches found." (length active-links)))))

(defun check-active-links ()
  (interactive)
  (let ((link-re "\\<[A-Z][a-z]+\\([A-Z][a-z]+\\)+\\>"))
    (list-active-links link-re)
    ;; Note: At this point we're in the "*ActiveLinks* buffer.
    (set (make-local-variable 'link-to-re) link-re)
    (local-set-key
     (kbd "C-c C-o")
     (lambda ()
       (interactive)
       (link-to link-to-re "\\<")))))